add installation instructions with CMake

CMakeLists.txt

@@ -76,4 +76,47 @@ endif()
 # installation
 # ------------------------------------------------------------------------------
 
-# TODO
+include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
+
+# install library file (.a/.so)
+install(
+        TARGETS evalhyd
+        EXPORT evalhyd-targets
+)
+
+# install headers
+install(
+        DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/evalhyd"
+        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
+        FILES_MATCHING PATTERN "*.hpp"
+)
+
+# generate target file
+export(
+        EXPORT evalhyd-targets
+        FILE "${CMAKE_CURRENT_BINARY_DIR}/EvalHydTargets.cmake"
+)
+
+# install target file
+install(
+        EXPORT evalhyd-targets
+        FILE "EvalHydTargets.cmake"
+        NAMESPACE EvalHyd::
+        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/EvalHyd
+)
+
+# generate config file
+configure_package_config_file(
+        EvalHydConfig.cmake.in
+        "${CMAKE_CURRENT_BINARY_DIR}/EvalHydConfig.cmake"
+        INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/EvalHyd
+)
+
+# install files
+install(
+        FILES
+            "${CMAKE_CURRENT_BINARY_DIR}/EvalHydConfig.cmake"
+        DESTINATION
+            "${CMAKE_INSTALL_LIBDIR}/cmake/EvalHyd"
+)

EvalHydConfig.cmake.in

+@PACKAGE_INIT@
+
+include(CMakeFindDependencyMacro)
+
+# find public dependencies
+find_dependency(xtensor @xtensor_VERSION@)
+
+if(NOT TARGET EvalHyd::evalhyd)
+    include("${CMAKE_CURRENT_LIST_DIR}/EvalHydTargets.cmake")
+endif()

README.md

@@ -20,3 +20,9 @@ Run tests with:
 ```shell
 ./build/tests/evalhyd_tests  
 ```
+
+## How to install
+
+```shell
+cmake --install build/ --prefix <path>
+```