assembly.smk

def khmer_input(wildcards):
	if config["SORTMERNA"]:
		return {"R1R2": "work/sortmerna/{wildcards.reads}_mRNA.fastq.gz".format(wildcards=wildcards)}
	else:
		return {"R1R2": "DATA/trim/{wildcards.reads}_R1R2.fastq.gz".format(wildcards=wildcards)}

rule khmer:
	input:
		unpack(khmer_input)
	output:
		R1R2 = "work/khmer/{reads}_R1R2.fastq.gz",
		log = "work/khmer/{reads}.log"
	threads:
		config["THREADS"]
	params:
		mem_tot = (config["MEM"] * config["THREADS"] * 1e9),
		K = 32,
		C = 100
	shell:
		"normalize-by-median.py "
		"--ksize {params.K} "
		"--max-memory-usage {params.mem_tot} "
		"--cutoff {params.C} "
		"--paired "
		"--report {output.log} "
		"--output {output.R1R2} "
		"--gzip "
		"{input.R1R2}"

def assembly_input(wildcards):
	if wildcards.reads == "coassembly":
		if config["NORMALIZATION"]:
			return [expand("work/khmer/{reads}_R1R2.fastq.gz", reads=SAMPLES)]
		elif config["SORTMERNA"]:
			return [expand("work/sortmerna/{reads}_mRNA.fastq.gz", reads=SAMPLES)]
		else:
			return [expand("DATA/trim/{reads}_R1R2.fastq.gz", reads=SAMPLES)]
	else:
		if config["NORMALIZATION"]:
			return {"R1R2": "work/khmer/{wildcards.reads}_R1R2.fastq.gz".format(wildcards=wildcards)}
		elif config["SORTMERNA"]:
			return {"R1R2": "work/sortmerna/{wildcards.reads}_mRNA.fastq.gz".format(wildcards=wildcards)}
		else:
			return {"R1R2": "DATA/trim/{wildcards.reads}_R1R2.fastq.gz".format(wildcards=wildcards)}

rule megahit:
	input:
		unpack(assembly_input)
	output:
		"work/megahit/{reads}/{reads}.contigs.fa"
	threads:
		config["THREADS"]
	params:
		min_len = config["CONTIGS_LEN"],
		mem_tot = int(config["MEM"] * config["THREADS"] * 1e9),
		input = lambda wildcards, input: ",".join(input),
		output = lambda wildcards, output: os.path.dirname(str(output))
	shell:
		"megahit "
		"--12 {params.input} "
		"--continue "
		"--preset meta-large "
		"--num-cpu-threads {threads} "
		"--memory {params.mem_tot} "
		"--out-dir {params.output} "
		"--out-prefix {wildcards.reads} "
		"--min-contig-len {params.min_len} "
		"--verbose"

rule metaspades: